home *** CD-ROM | disk | FTP | other *** search
/ The Very Best of Atari Inside / The Very Best of Atari Inside 1.iso / mint / mntlb20 / lib / sozobon / bcopy.s < prev    next >
Text File  |  1992-01-11  |  2KB  |  83 lines
  1. ; void bcopy(void *src, void *dst, long cnt)
  2. ;    handle overlap (both ways), odd/even alignment etc
  3. ;    ++jrb    bammi@dsrgsun.ces.cwru.edu
  4. ; 
  5.     .text
  6.     .even
  7.     .globl _bcopy
  8. _bcopy:
  9.     move.l    4(sp),a0    ; src -> a0
  10.     move.l    8(sp),a1    ; dst -> a1
  11.     move.l    12(sp),d0    ; cnt -> d0
  12.     ble    return        ; cnt <= 0
  13.     move.l    d2,-(sp)    ; save d2
  14.  
  15.     ; check overlap
  16.     move.l    a0,d1        ; (abs(src - dst)) < cnt =>  overlap
  17.     sub.l    a1,d1
  18.     bge    L1
  19.     neg.l    d1
  20. L1:    cmp.l    d1,d0
  21.     bgt    overlap
  22.  
  23.     ; check for odd src or dst
  24.     move.w    a0,d1
  25.     move.w    a1,d2
  26.     eor.b    d1,d2
  27.     btst    #0,d2
  28.     bne    oddeven
  29.     btst    #0,d1
  30.     beq    eveneven
  31.     move.b    (a0)+,(a1)+    ; odd  odd
  32.     subq.l    #1,d0        ; now even even 
  33.  
  34. eveneven:            ; may want long alignment for 020/030 etc
  35.     move.l    d0,d1
  36.     and.b    #$1c,d1        ; 4 bytes/copy  32 bytes max/iter
  37.     lsr.l    #1,d1        ; calc index into loop (each move.l == 2bytes)
  38.     neg.l    d1        ;  
  39.     add.l    #18,d1        ; 16 + 2 bytes for jmp ext word - d1 == index
  40.     jmp    0(pc,d1)    ;  dive into loop at appro spot
  41. loop1:
  42.     move.l    (a0)+,(a1)+
  43.     move.l    (a0)+,(a1)+
  44.     move.l    (a0)+,(a1)+
  45.     move.l    (a0)+,(a1)+
  46.  
  47.     move.l    (a0)+,(a1)+
  48.     move.l    (a0)+,(a1)+
  49.     move.l    (a0)+,(a1)+
  50.     move.l    (a0)+,(a1)+
  51.  
  52.     sub.l    #32,d0
  53.     bge    loop1
  54.  
  55.     btst    #1,d0
  56.     beq    L4
  57.     move.w    (a0)+,(a1)+    ; residual word
  58. L4:    btst    #0,d0
  59.     beq    ret
  60.     move.b    (a0),(a1)        ; residual byte
  61.  
  62. ret:    move.l    (sp)+,d2
  63. return:    rts
  64.  
  65. oddeven:
  66. upcopy:                ; byte-by-byte forward
  67.     subq.l    #1,d0
  68.     blt    ret
  69.     move.b    (a0)+,(a1)+
  70.     bra    upcopy
  71.  
  72. overlap:
  73.     cmp.l    a0,a1
  74.     bmi    upcopy        ; (src > dst) go do byte/byte forward copy
  75.     add.l    d0,a0        ; otherwise backwards copy
  76.     add.l    d0,a1        ; note we use predec so 1 is not sub from addr
  77.  
  78. downcopy:            ; byte-by-byte backward
  79.     subq.l    #1,d0
  80.     blt    ret
  81.     move.b    -(a0),-(a1)
  82.     bra    downcopy
  83.